CONTAR.SI: descubre esta práctica función de Excel

Si utilizas Excel solo para crear tablas a mano debes saber que estás subestimando a la herramienta de Microsoft, pues esta tiene numerosas funciones de gran utilidad para simplificar el trabajo tanto en el ámbito privado como en el laboral. Para beneficiarse de las ventajas del programa de hojas de cálculo es necesario comprender sus funciones, entre otras la función CONTAR.SI (en inglés COUNTIF). ¿Para qué se utiliza CONTAR.SI y cómo se utiliza correctamente?

Excel con Office 365 y 1&1 IONOS

Incluido en cada pack Office 365, usa Excel para organizar tus datos y ahorrarte tiempo. ¡Desde sólo 4€/mes!

 OneDrive con 1TB
 Office Online
 Asistencia 24/7

¿Para qué se utiliza CONTAR.SI de Excel?

Imagina que tienes una lista sin clasificar con entradas que reflejan, por ejemplo, las ventas de los últimos meses, pero quieres averiguar la asiduidad con la que se vende un artículo determinado. En lugar de examinar a mano toda la lista, utiliza para ello la función CONTAR.SI de Excel, con la que también puede contarse si se aplica un valor determinado.

CONTAR.SI de Excel es una función estadística. Como se puede ver en el ejemplo, esta se utiliza para crear estadísticas. Si se aplica la pregunta “¿con qué frecuencia se vende el artículo XY?” a cada producto disponible, puede averiguarse cuáles son los artículos más populares. Seguidamente, con los datos estadísticos pueden crearse, por ejemplo, diagramas.

En principio, CONTAR.SI consiste en una combinación de las funciones SI (función lógica) y CONTAR o CONTARA (funciones estadísticas). Dicha combinación da como resultado que Excel solo cuente una celda si se cumple un valor determinado.

Sin embargo, no debe confundirse CONTAR.SI con SUMAR.SI. Esta función similar no ofrece el número de valores dentro de un área de datos, sino que suma directamente las cantidades especificadas. En nuestro ejemplo, el artículo en cuestión se comercializa por campañas en grandes cantidades y la función SUMAR.SI determina el número de productos vendidos.

¿Cómo se utiliza la función CONTAR.SI de Excel correctamente?

En las funciones de Excel es importante respetar la sintaxis adecuada:

                =CONTAR.SI(rango;criterio de búsqueda)

EL concepto rango hace referencia a las celdas de una tabla que recogen los datos que deben contarse. El criterio de búsqueda ofrece el valor correspondiente que debe considerarse. En el rango se indica la celda inicial y la celda final, separadas por dos puntos. La entrada “B3:B14” comprende tanto las dos celdas mencionadas como todas las situadas entre ellas. Como alternativa, Excel también ofrece la posibilidad de mover rangos con el ratón. Los rangos de celdas correspondientes se marcan en color, pero también es posible marcar toda la columna, en cuyo caso solo se ofrece la columna como valor, pero no las filas: “B:B”. Esto funciona de la misma manera con las filas.

El criterio de búsqueda puede indicarse como valor, en cuyo caso irá entre comillas (por ejemplo, “zapatos”) o también puede hacerse referencia a una celda en la que se encuentre dicho valor (por ejemplo, B3). Ambas entradas (rango y criterio de búsqueda) se separan con punto y coma, pero sin que haya espacios en blanco en la sintaxis:

                =CONTAR.SI(B3:B14;"zapatos")

                =CONTAR.SI(B3:B14;F3)

Nota

Las funciones de Excel siempre van precedidas del signo igual, pues de lo contrario el programa interpreta los datos como una cadena de caracteres sencilla y la escribe de manera visible en la celda.

Pero Excel también ofrece útiles funciones de autocompletado. Desplaza a la función (en la parte inferior derecha de la celda activada en la que se hace clic) una fila más adelante: las celdas especificadas en rango y criterio de búsqueda se ajustan automáticamente, por lo que la función hace referencia ahora a las celdas situadas una línea más abajo. Si no se desea este cambio debido a que el rango de búsqueda debe permanecer invariable, puedes especificar estos datos como valores absolutos. Introduce para ello el símbolo del dólar:

                =CONTAR.SI($B$3:$B$14;F3)

CONTAR.SI de Excel tiene otra función adicional llamada CONTAR.SI.CONJUNTO, que permite añadir más rangos y valores de búsqueda a las funciones. Así, por ejemplo, puedes calcular las ventas de zapatos que incluyen más de un producto.

=CONTAR.SI.CONJUNTO(B3:B14;$G4;C3:C14;>1)

Nota

CONTAR.SI de Excel no tiene en cuenta las mayúsculas o las minúsculas.

La función CONTAR.SI explicada con ejemplos

Imagina que tienes una tienda y para tus estadísticas quieres averiguar el número de compradores de tu entorno directo. Para ello, se les ha preguntado a todos los clientes si estarían dispuestos a facilitar su código postal, tras lo que se incluyen las entradas una detrás de otra en una tabla. Las celdas pueden contarse, por ejemplo, si en ellas se encuentra tu código postal.

                =CONTAR.SI(B3:B17;"10969")

Consejo

En nuestro ejemplo utilizamos cifras como texto. En principio, esto no supone ninguna diferencia para CONTAR.SI de Excel, pero para que no surjan problemas en otras situaciones, las celdas deben formatearse como texto.

Así se obtiene como resultado el número de clientes que vive cerca de tu tienda. Si quieres saber el resultado contrario, es decir, el número de personas que proceden de otro código postal, introduce el signo de menor que (<) y el de mayor que (>) antes del criterio de búsqueda.

                =CONTAR.SI(B3:B17;"<>10969")

Si no quieres introducir el valor directamente en la función y, por el contrario, hacer referencia a este en una celda determinada, debes enlazar la negación (“<>”) con el operador de concatenación (&) con la celda.

                =CONTAR.SI(B3:B17;"<>"&B3)

También se ha preguntado a los clientes por su edad y se han introducido los datos asignados a los códigos postales correspondientes en una columna. Se puede suponer que la oferta resulta atractiva para personas de más de 50 años, pero para verificarlo, puedes utilizar la función CONTAR.SI de Excel. Dado que tu objetivo no es solo dirigirte a clientes de más de 50 años, sino también a los de esa edad exacta, la función debe contener los símbolos de más y menos que y de igual:

                =CONTAR.SI(C3:C17; ">=50")

También es interesante el resultado negativo, es decir, el número de personas que son menores de 50. Para ello no es necesaria la negación, sino solo el símbolo menor que:

                =CONTAR.SI(C3:C17; "<50")

Si alguien no facilita los datos sobre su edad, este valor será simplemente extraído. La eliminación de un código postal que no sea 10969 no influye en el resultado final. Aquí puedes ampliar la fórmula contando todas las celdas vacías y restando la cifra al primer resultado. Para informar a Excel de que quieres utilizar las celdas vacías como criterio de búsqueda, deja vacío el rango entre las dos comillas y escribe estos dos símbolos directamente uno detrás del otro:

                =CONTAR.SI(B3:B17;"<>10969")-CONTAR.SI(B3:B17;"")

Como alternativa puedes utilizar la función avanzada CONTAR.SI.CONJUNTO. Para ello se introduce otro criterio de búsqueda en la fórmula original, este es, el de no añadir celdas vacías. Por lo tanto, las celdas vacías no se restan, sino que se excluyen directamente del recuento:

                =CONTAR.SI.CONJUNTO(B3:B17;"<>10969";B3:B17;"<>")

Si a continuación quieres averiguar, por el motivo que sea, cuántos clientes de más de 50 años proceden de tu código postal, puedes recurrir a la función CONTAR.SI.CONJUNTO, para lo que tendrás que introducir el valor adicional en la fórmula:

                =CONTAR.SI.CONJUNTO (B3:B17;"10969";B3:B17;"<>";C3:C17;">=50")

Nota

En la función CONTAR.SI, Excel tiene problemas con las secuencias largas de caracteres. Para utilizar valores de búsqueda de más de 255 caracteres puedes unir los valores entre sí. Para ello utiliza el operador de concatenación “&”: =CONTAR.SI (B3:B17;"109"&"69").

De la encuesta realizada también se han obtenido datos sobre lo que los clientes han comprado. Si se es el propietario de una tienda de zapatos, interesa conocer con qué frecuencia se han vendido unos determinados tipos de zapatos, por lo tanto, solo quieren tenerse en cuenta estas ventas. Para ello puede utilizare un carácter comodín, que en Excel se indica con el asterisco (*):

                =CONTAR.SI (D3:D17;"*zapatos")

Nota

Los caracteres comodín funcionan únicamente para entradas de texto, pero no para valores numéricos. Lo mismo es de aplicación para el símbolo de interrogación (?) como carácter comodín, que puede reemplazar a un único carácter. Pero si quieres buscar un símbolo de interrogación o un asterisco, debes enmascararlo colocando una virgulilla (~) delante del símbolo.